Re: [Caml-list] Good examples for a Camlp4 beginner?

["Alexander V. Voinov" <avv@quasar.ipa.nw.ru>]

[-- Attachment #1: Type: text/plain, Size: 807 bytes --]

Hi Matt,

See a simple extension, which adds some sugar on top of the List module 
functionality. My purpose in this case was to give close analogs to 
Python's loops over sequences (e.g. lists), to facilitate transition. An 
example is attached as well.

Alexander

Matt Gushee wrote:

>Hello, all--
>
>Over the past couple of weeks I have been learning about the various
>OCaml parsing and lexing tools, with an emphasis on Camlp4. It's
>fascinating, and I've learned a lot, but I am still having trouble
>grasping how the different components fit together. I think what I need
>now is to look at some examples of working, real-world code that use
>Camlp4 ... something non-trivial, but not enormously complex. Can anyone
>suggest a good place to start?
>
>Thanks in advance for any suggestions.
>
>  
>


[-- Attachment #2: listsugar.ml --]
[-- Type: text/plain, Size: 957 bytes --]

open Pcaml;;

EXTEND
  GLOBAL: expr;

  expr: 
    [ [ "map"; list = expr; "with"; OPT "|"; clauses = LIST1 clause SEP "|" ->
	  <:expr< List.map (fun [ $list:clauses$ ]) $list$ >> ]

    | [ "iterate"; list = expr; "with"; OPT "|"; clauses = LIST1 clause SEP "|" ->
	  <:expr< List.iter (fun [ $list:clauses$ ]) $list$ >> ]
	
    | [ "foldr"; list = expr; "from"; initval = expr; "with"; OPT "|"; 
	clauses = LIST1 clause SEP "|" ->
	  <:expr< List.fold_right (fun a b -> 
				     match (a, b) with [ $list:clauses$ ]) 
	                           $list$ $initval$ >> ]

    | [ "foldl"; list = expr; "from"; initval = expr; "with"; OPT "|"; 
	clauses = LIST1 clause SEP "|" ->
	  <:expr< List.fold_left (fun a b -> 
				     match (a, b) with [ $list:clauses$ ]) 
	                           $initval$ $list$ >> ]
    ];

  clause:
    [[ p = patt; w = OPT when_expr; "->"; e = expr -> (p, w, e)]];

  when_expr:
    [[ "when"; e = expr -> e ]];
END;;



[-- Attachment #3: testsugar.ml --]
[-- Type: text/plain, Size: 973 bytes --]

open Printf

let _ =
  let values = [1; 2; 3; 4; 5; 6; 7] in

  let vals2 = 
    map values with
      | 1 | 3 | 7 -> 10
      | v when v mod 2 == 0 -> v + 1 
      | v -> v - 1
  in

  let valfmtd = String.concat ", " (map vals2 with v -> sprintf "<%d>" v) in

  let suml, sumsquares, nelem = 
    foldl values from 0.0, 0.0, 0 with 
	(suml0, sumsq0, n), value -> 
	  let fv = float value in 
	  (suml0 +. fv, sumsq0 +. fv *. fv, n + 1) 
  in
  let mean = suml /. float nelem in
  let sdev = sqrt ((sumsquares -. float nelem *. mean *. mean) 
		   /. (float nelem -. 1.0)) in

  let sumr = 
    foldr values from 0.0 with 
	value, sum0 -> (
	  printf "found value = %d, sum0 = %5.2f\n" value sum0;
	  sum0 +. float value
	) 
  in

  printf "%s\n" valfmtd;
  printf "mean: %g, sdev: %g\n" mean sdev;
  printf "sumr: %g\n" sumr;

  iterate values with
    | 1 -> printf "one\n"
    | v when v mod 2 == 0 -> printf "%d is even\n" v
    | v -> printf "%d is odd\n" v